Claus,

You can also try param3d1, which needs to be called only once:

// START OF CODE
frequencies = [201 811 3183 12862 25113]; // Hz;
angles = [0 30 60 90]; // degrees
m_norm = [ 1.0   0.9945629   0.9643959   0.8756431;
           1.0   0.9914442   1.0244046   0.9414654;
           1.0   0.9910279   0.9670986   0.8932413;
           1.0   0.9339808   0.8378147   0.7067978;
           1.0   0.8985782   0.7536068   0.5074218];
[nf na] = size(m_norm)
A = (angles .*. ones(nf,1))';
F = (frequencies .*. ones(na,1));
M = 20*log10(m_norm'); // dB scale
clf();
sp = gca();
param3d1(F,A,M,alpha=50,theta=-110,flag=[2,4]);
e = gce();
for i=1:nf;
    e.children(i).foreground = color('dark blue');
    e.children(i).thickness = 2;
end
xgrid;
sp.log_flags = "lnn"; // x-axis log scale (frequencies)
sp.cube_scaling = "on";
xlabel("Frequency (Hz)");
ylabel("Angle (deg)");
zlabel("Mag (dB)");
// END OF CODE

Regards,
Rafael


        
        
        
<br/><hr align="left" width="300" />
Sent from the <a href="http://mailinglists.scilab.org/Scilab-users-Mailing-Lists-Archives-f2602246.html">Scilab users - Mailing Lists Archives mailing list archive</a> at Nabble.com.<br/>